overlays: add sabnzbd-fix-missing-dependencies

While waiting for my PR to fix this [1].

[1]: https://github.com/NixOS/nixpkgs/pull/140478

overlays/default.nix

@@ -1,3 +1,5 @@
 {
+  sabnzbd-fix-missing-packages = import ./sabnzbd-fix-missing-dependencies;
+
   transgui-fix-duplicate-status = import ./transgui-fix-duplicate-status;
 }

overlays/sabnzbd-fix-missing-dependencies/default.nix

@@ -0,0 +1,4 @@
+final: prev:
+{
+  sabnzbd = final.callPackage ./sabnzbd.nix { };
+}

overlays/sabnzbd-fix-missing-dependencies/sabnzbd.nix

@@ -0,0 +1,60 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, python3
+, par2cmdline
+, unzip
+, unrar
+, p7zip
+, makeWrapper
+}:
+
+let
+  pythonEnv = python3.withPackages (ps: with ps; [
+    chardet
+    cheetah3
+    cherrypy
+    configobj
+    cryptography
+    feedparser
+    guessit
+    puremagic
+    sabyenc3
+  ]);
+  path = lib.makeBinPath [ par2cmdline unrar unzip p7zip ];
+in
+stdenv.mkDerivation rec {
+  version = "3.4.0";
+  pname = "sabnzbd";
+
+  src = fetchFromGitHub {
+    owner = pname;
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-zax+PuvCmYOlEhRmiCp7UOd9VI0i8dbgTPyTtqLuGUM=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ pythonEnv ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    cp -R * $out/
+    mkdir $out/bin
+    echo "${pythonEnv}/bin/python $out/SABnzbd.py \$*" > $out/bin/sabnzbd
+    chmod +x $out/bin/sabnzbd
+    wrapProgram $out/bin/sabnzbd --set PATH ${path}
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Usenet NZB downloader, par2 repairer and auto extracting server";
+    homepage = "https://sabnzbd.org";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with lib.maintainers; [ fridh ];
+  };
+}