Bruno BELANYI
cb45ece777
Some checks failed
ci/woodpecker/push/check Pipeline failed
Ideally, I'd like for `delta` to just read a configuration file at `$XDG_CONFIG_HOME/delta/config` by default, but upstream seems somewhat reticent to the idea :-/. So instead, let's keep relying on `git` being enabled, but rather than inlining the configuration, let's store it where I think it should belong and include it into `gitconfig`.
79 lines
1.9 KiB
Nix
79 lines
1.9 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
let
|
|
cfg = config.my.home.delta;
|
|
|
|
configFormat = pkgs.formats.gitIni { };
|
|
configPath = "${config.xdg.configHome}/delta/config";
|
|
in
|
|
{
|
|
options.my.home.delta = with lib; {
|
|
enable = my.mkDisableOption "delta configuration";
|
|
|
|
package = mkPackageOption pkgs "delta" { };
|
|
|
|
git = {
|
|
enable = my.mkDisableOption "git integration";
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
{
|
|
# For its configuration
|
|
assertion = cfg.enable -> cfg.git.enable;
|
|
message = ''
|
|
`config.my.home.delta` must enable `config.my.home.delta.git` to be
|
|
properly configured.
|
|
'';
|
|
}
|
|
{
|
|
assertion = cfg.enable -> config.programs.git.enable;
|
|
message = ''
|
|
`config.my.home.delta` relies on `config.programs.git` to be
|
|
enabled.
|
|
'';
|
|
}
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
xdg.configFile."delta/config".source = configFormat.generate "delta-config" {
|
|
delta = {
|
|
features = "diff-highlight decorations";
|
|
|
|
# Less jarring style for `diff-highlight` emulation
|
|
diff-highlight = {
|
|
minus-style = "red";
|
|
minus-non-emph-style = "red";
|
|
minus-emph-style = "bold red 52";
|
|
|
|
plus-style = "green";
|
|
plus-non-emph-style = "green";
|
|
plus-emph-style = "bold green 22";
|
|
|
|
whitespace-error-style = "reverse red";
|
|
};
|
|
|
|
# Personal preference for easier reading
|
|
decorations = {
|
|
commit-style = "raw"; # Do not recolor meta information
|
|
keep-plus-minus-markers = true;
|
|
paging = "always";
|
|
};
|
|
};
|
|
};
|
|
|
|
programs.git = lib.mkIf cfg.git.enable {
|
|
delta = {
|
|
enable = true;
|
|
inherit (cfg) package;
|
|
};
|
|
|
|
includes = [
|
|
{
|
|
path = configPath;
|
|
}
|
|
];
|
|
};
|
|
};
|
|
}
|