home: comma: configure custom 'nixpkgs' flake

This makes use of my pinned `pkgs` flake from the registry by default.

home/comma.nix

@@ -0,0 +1,29 @@
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.my.home.comma;
+in
+{
+  options.my.home.comma = with lib; {
+    enable = my.mkDisableOption "comma configuration";
+
+    pkgsFlake = mkOption {
+      type = types.str;
+      default = "pkgs";
+      example = "nixpkgs";
+      description = ''
+        Which flake from the registry should be used with
+        <command>nix shell</command>.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    home.packages = with pkgs; [
+      ambroisie.comma
+    ];
+
+    home.sessionVariables = {
+      COMMA_PKGS_FLAKE = cfg.pkgsFlake;
+    };
+  };
+}

home/default.nix

@@ -3,6 +3,7 @@
   imports = [
     ./bat.nix
     ./bluetooth.nix
+    ./comma.nix
     ./direnv.nix
     ./documentation.nix
     ./feh.nix

home/packages.nix

@@ -18,7 +18,6 @@ in
   };
 
   config.home.packages = with pkgs; lib.mkIf cfg.enable ([
-    ambroisie.comma
     file
     gitAndTools.git-absorb
     gitAndTools.git-revise

pkgs/comma/comma

@@ -30,4 +30,4 @@ if [ -z "$PROGRAM" ]; then
     exit 1
 fi
 
-nix shell "nixpkgs#$PROGRAM" -c "$@"
+nix shell "${COMMA_PKGS_FLAKE:-nixpkgs}#$PROGRAM" -c "$@"

pkgs/default.nix

@@ -18,6 +18,8 @@ rec {
 
   vimix-cursors = pkgs.callPackage ./vimix-cursors { };
 
+  volantes-cursors = pkgs.callPackage ./volantes-cursors { };
+
   unbound-zones-adblock = pkgs.callPackage ./unbound-zones-adblock {
     inherit unified-hosts-lists;
   };

pkgs/volantes-cursors/default.nix

@@ -0,0 +1,44 @@
+{ fetchFromGitHub, inkscape, lib, stdenvNoCC, xcursorgen }:
+stdenvNoCC.mkDerivation rec {
+  pname = "volantes-cursors";
+  version = "unstable-2020-06-06";
+
+  src = fetchFromGitHub {
+    owner = "varlesh";
+    repo = pname;
+    rev = "d1d290ff42cc4fa643716551bd0b02582b90fd2f";
+    sha256 = "sha256-irMN/enoo90nYLfvSOScZoYdvhZKvqqp+grZB2BQD9o=";
+  };
+
+  nativeBuildInputs = [
+    inkscape
+    xcursorgen
+  ];
+
+  postPatch = ''
+    patchShebangs .
+    # The script tries to build in its source directory...
+    substituteInPlace build.sh --replace \
+      ': "''${BUILD_DIR:="$SCRIPT_DIR"/build}"' \
+      "BUILD_DIR=$(pwd)/build"
+    substituteInPlace build.sh --replace \
+      ': "''${OUT_DIR:="$SCRIPT_DIR"/dist}"' \
+      "OUT_DIR=$(pwd)/dist"
+  '';
+
+  buildPhase = ''
+    HOME="$NIX_BUILD_ROOT" ./build.sh
+  '';
+
+  installPhase = ''
+    make install PREFIX= DESTDIR=$out/
+  '';
+
+  meta = with lib; {
+    description = "Classic cursor with a flying style";
+    homepage = "https://github.com/varlesh/volantes-cursors";
+    license = licenses.gpl2Only;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ ambroisie ];
+  };
+}