From f54cee8f70cd569fcc77093e7330f327ee1b3970 Mon Sep 17 00:00:00 2001
From: Bruno BELANYI <bruno@belanyi.fr>
Date: Sun, 4 Feb 2024 14:37:31 +0000
Subject: [PATCH] nixos: hardware: add graphics

I did not add an Nvidia knob to this module, as I do not foresee *ever*
using one of their graphics card.
---
 modules/nixos/hardware/default.nix          |  1 +
 modules/nixos/hardware/graphics/default.nix | 75 +++++++++++++++++++++
 2 files changed, 76 insertions(+)
 create mode 100644 modules/nixos/hardware/graphics/default.nix

diff --git a/modules/nixos/hardware/default.nix b/modules/nixos/hardware/default.nix
index 2a686f7..95e6a22 100644
--- a/modules/nixos/hardware/default.nix
+++ b/modules/nixos/hardware/default.nix
@@ -6,6 +6,7 @@
     ./bluetooth
     ./ergodox
     ./firmware
+    ./graphics
     ./mx-ergo
     ./networking
     ./sound
diff --git a/modules/nixos/hardware/graphics/default.nix b/modules/nixos/hardware/graphics/default.nix
new file mode 100644
index 0000000..3baac02
--- /dev/null
+++ b/modules/nixos/hardware/graphics/default.nix
@@ -0,0 +1,75 @@
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.my.hardware.graphics;
+in
+{
+  options.my.hardware.graphics = with lib; {
+    enable = mkEnableOption "graphics configuration";
+
+    gpuFlavor = mkOption {
+      type = with types; nullOr (enum [ "amd" "intel" ]);
+      default = null;
+      example = "intel";
+      description = "Which kind of GPU to install driver for";
+    };
+
+    amd = {
+      enableKernelModule = lib.my.mkDisableOption "Kernel driver module";
+
+      amdvlk = lib.mkEnableOption "Use AMDVLK instead of Mesa RADV driver";
+    };
+
+    intel = {
+      enableKernelModule = lib.my.mkDisableOption "Kernel driver module";
+    };
+  };
+
+  config = lib.mkIf cfg.enable (lib.mkMerge [
+    {
+      hardware.opengl = {
+        enable = true;
+      };
+    }
+
+    # AMD GPU
+    (lib.mkIf (cfg.gpuFlavor == "amd") {
+      boot.initrd.kernelModules = lib.mkIf cfg.amd.enableKernelModule [ "amdgpu" ];
+
+      hardware.opengl = {
+        extraPackages = with pkgs; [
+          # OpenCL
+          rocmPackages.clr
+          rocmPackages.clr.icd
+        ]
+        ++ lib.optional cfg.amd.amdvlk amdvlk
+        ;
+
+        extraPackages32 = with pkgs; [
+        ]
+        ++ lib.optional cfg.amd.amdvlk driversi686Linux.amdvlk
+        ;
+      };
+    })
+
+    # Intel GPU
+    (lib.mkIf (cfg.gpuFlavor == "intel") {
+      boot.initrd.kernelModules = lib.mkIf cfg.intel.enableKernelModule [ "i915" ];
+
+      environment.variables = {
+        VDPAU_DRIVER = "va_gl";
+      };
+
+      hardware.opengl = {
+        extraPackages = with pkgs; [
+          # Open CL
+          intel-compute-runtime
+
+          # VA API
+          intel-media-driver
+          intel-vaapi-driver
+          libvdpau-va-gl
+        ];
+      };
+    })
+  ]);
+}