nixos: create 'modules/nixos' folder

Let's consolidate all modules under one path, so that NixOS,
home-manager, and nix-darwin (if I ever end up using it down the line)
would go under the same folder.

modules/nixos/hardware/bluetooth/default.nix

@@ -0,0 +1,56 @@
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.my.hardware.bluetooth;
+in
+{
+  options.my.hardware.bluetooth = with lib; {
+    enable = mkEnableOption "bluetooth configuration";
+
+    enableHeadsetIntegration = my.mkDisableOption "A2DP sink configuration";
+
+    loadExtraCodecs = my.mkDisableOption "extra audio codecs";
+  };
+
+  config = lib.mkIf cfg.enable (lib.mkMerge [
+    # Enable bluetooth devices and GUI to connect to them
+    {
+      hardware.bluetooth.enable = true;
+      services.blueman.enable = true;
+    }
+
+    # Support for additional bluetooth codecs
+    (lib.mkIf cfg.loadExtraCodecs {
+      hardware.pulseaudio = {
+        extraModules = [ pkgs.pulseaudio-modules-bt ];
+        package = pkgs.pulseaudioFull;
+      };
+
+      environment.etc = {
+        "wireplumber/bluetooth.lua.d/51-bluez-config.lua".text = ''
+          bluez_monitor.properties = {
+            -- SBC XQ provides better audio
+            ["bluez5.enable-sbc-xq"] = true,
+
+            -- mSBC provides better audio + microphone
+            ["bluez5.enable-msbc"] = true,
+
+            -- Synchronize volume with bluetooth device
+            ["bluez5.enable-hw-volume"] = true,
+
+            -- FIXME: Some devices may now support both hsp_ag and hfp_ag
+            ["bluez5.headset-roles"] = "[ hsp_hs hsp_ag hfp_hf hfp_ag ]"
+          }
+        '';
+      };
+    })
+
+    # Support for A2DP audio profile
+    (lib.mkIf cfg.enableHeadsetIntegration {
+      hardware.bluetooth.settings = {
+        General = {
+          Enable = "Source,Sink,Media,Socket";
+        };
+      };
+    })
+  ]);
+}

modules/nixos/hardware/default.nix

@@ -0,0 +1,14 @@
+# Hardware-related modules
+{ ... }:
+
+{
+  imports = [
+    ./bluetooth
+    ./ergodox
+    ./firmware
+    ./mx-ergo
+    ./networking
+    ./sound
+    ./upower
+  ];
+}

modules/nixos/hardware/ergodox/default.nix

@@ -0,0 +1,14 @@
+# ZSA keyboard udev rules
+{ config, lib, ... }:
+let
+  cfg = config.my.hardware.ergodox;
+in
+{
+  options.my.hardware.ergodox = with lib; {
+    enable = mkEnableOption "ZSA udev rules and user group configuration";
+  };
+
+  config = lib.mkIf cfg.enable {
+    hardware.keyboard.zsa.enable = true;
+  };
+}

modules/nixos/hardware/firmware/default.nix

@@ -0,0 +1,38 @@
+{ config, lib, ... }:
+let
+  cfg = config.my.hardware.firmware;
+in
+{
+  options.my.hardware.firmware = with lib; {
+    enable = my.mkDisableOption "firmware configuration";
+
+    cpuFlavor = mkOption {
+      type = with types; nullOr (enum [ "intel" "amd" ]);
+      default = null;
+      example = "intel";
+      description = "Which kind of CPU to activate micro-code updates";
+    };
+  };
+
+  config = lib.mkIf cfg.enable (lib.mkMerge [
+    {
+      hardware = {
+        enableRedistributableFirmware = true;
+      };
+    }
+
+    # Intel CPU
+    (lib.mkIf (cfg.cpuFlavor == "intel") {
+      hardware = {
+        cpu.intel.updateMicrocode = true;
+      };
+    })
+
+    # AMD CPU
+    (lib.mkIf (cfg.cpuFlavor == "amd") {
+      hardware = {
+        cpu.amd.updateMicrocode = true;
+      };
+    })
+  ]);
+}

modules/nixos/hardware/mx-ergo/default.nix

@@ -0,0 +1,26 @@
+# Hold down the `next page` button to scroll using the ball
+{ config, lib, ... }:
+let
+  cfg = config.my.hardware.mx-ergo;
+in
+{
+  options.my.hardware.mx-ergo = with lib; {
+    enable = mkEnableOption "MX Ergo configuration";
+  };
+
+  config = lib.mkIf cfg.enable {
+    services.xserver = {
+      # This section must be *after* the one configured by `libinput`
+      # for the `ScrollMethod` configuration to not be overriden
+      inputClassSections = lib.mkAfter [
+        ''
+          Identifier      "MX Ergo scroll button configuration"
+          MatchProduct    "MX Ergo"
+          MatchIsPointer  "on"
+          Option          "ScrollMethod"    "button"
+          Option          "ScrollButton"    "9"
+        ''
+      ];
+    };
+  };
+}

modules/nixos/hardware/networking/default.nix

@@ -0,0 +1,27 @@
+{ config, lib, ... }:
+let
+  cfg = config.my.hardware.networking;
+in
+{
+  options.my.hardware.networking = with lib; {
+    externalInterface = mkOption {
+      type = types.nullOr types.str;
+      default = null;
+      example = "eth0";
+      description = ''
+        Name of the network interface that egresses to the internet. Used for
+        e.g. NATing internal networks.
+      '';
+    };
+
+    wireless = {
+      enable = mkEnableOption "wireless configuration";
+    };
+  };
+
+  config = lib.mkMerge [
+    (lib.mkIf cfg.wireless.enable {
+      networking.networkmanager.enable = true;
+    })
+  ];
+}

modules/nixos/hardware/sound/default.nix

@@ -0,0 +1,63 @@
+{ config, lib, ... }:
+let
+  cfg = config.my.hardware.sound;
+in
+{
+  options.my.hardware.sound = with lib; {
+    pipewire = {
+      enable = mkEnableOption "pipewire configuration";
+    };
+
+    pulse = {
+      enable = mkEnableOption "pulseaudio configuration";
+    };
+  };
+
+  config = (lib.mkMerge [
+    # Sanity check
+    {
+      assertions = [
+        {
+          assertion = builtins.all (lib.id) [
+            (cfg.pipewire.enable -> !cfg.pulse.enable)
+            (cfg.pulse.enable -> !cfg.pipewire.enable)
+          ];
+          message = ''
+            `config.my.hardware.sound.pipewire.enable` and
+            `config.my.hardware.sound.pulse.enable` are incompatible.
+          '';
+        }
+      ];
+    }
+
+    (lib.mkIf cfg.pipewire.enable {
+      # RealtimeKit is recommended
+      security.rtkit.enable = true;
+
+      services.pipewire = {
+        enable = true;
+
+        alsa = {
+          enable = true;
+          support32Bit = true;
+        };
+
+        pulse = {
+          enable = true;
+        };
+
+        jack = {
+          enable = true;
+        };
+      };
+    })
+
+    # Pulseaudio setup
+    (lib.mkIf cfg.pulse.enable {
+      # ALSA
+      sound.enable = true;
+
+      hardware.pulseaudio.enable = true;
+    })
+  ]);
+}

modules/nixos/hardware/upower/default.nix

@@ -0,0 +1,44 @@
+{ config, lib, ... }:
+let
+  cfg = config.my.hardware.upower;
+in
+{
+  options.my.hardware.upower = with lib; {
+    enable = mkEnableOption "upower configuration";
+
+    levels = {
+      low = mkOption {
+        type = types.ints.unsigned;
+        default = 25;
+        example = 10;
+        description = "Low percentage";
+      };
+
+      critical = mkOption {
+        type = types.ints.unsigned;
+        default = 15;
+        example = 5;
+        description = "Critical percentage";
+      };
+
+      action = mkOption {
+        type = types.ints.unsigned;
+        default = 5;
+        example = 3;
+        description = "Percentage at which point an action must be taken";
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    services.upower = {
+      enable = true;
+
+      percentageLow = cfg.levels.low;
+
+      percentageCritical = cfg.levels.critical;
+
+      percentageAction = cfg.levels.action;
+    };
+  };
+}