From b8f1f85bc269245dbb2d7446efaa00e3eb7ffe71 Mon Sep 17 00:00:00 2001
From: Bruno BELANYI <bruno@belanyi.fr>
Date: Thu, 27 May 2021 19:57:31 +0200
Subject: [PATCH] pkgs: add volantes-cursors

---
 pkgs/default.nix                  |  2 ++
 pkgs/volantes-cursors/default.nix | 44 +++++++++++++++++++++++++++++++
 2 files changed, 46 insertions(+)
 create mode 100644 pkgs/volantes-cursors/default.nix

diff --git a/pkgs/default.nix b/pkgs/default.nix
index 380ee0b..7419501 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -18,6 +18,8 @@ rec {
 
   vimix-cursors = pkgs.callPackage ./vimix-cursors { };
 
+  volantes-cursors = pkgs.callPackage ./volantes-cursors { };
+
   unbound-zones-adblock = pkgs.callPackage ./unbound-zones-adblock {
     inherit unified-hosts-lists;
   };
diff --git a/pkgs/volantes-cursors/default.nix b/pkgs/volantes-cursors/default.nix
new file mode 100644
index 0000000..08cec66
--- /dev/null
+++ b/pkgs/volantes-cursors/default.nix
@@ -0,0 +1,44 @@
+{ fetchFromGitHub, inkscape, lib, stdenvNoCC, xcursorgen }:
+stdenvNoCC.mkDerivation rec {
+  pname = "volantes-cursors";
+  version = "unstable-2020-06-06";
+
+  src = fetchFromGitHub {
+    owner = "varlesh";
+    repo = pname;
+    rev = "d1d290ff42cc4fa643716551bd0b02582b90fd2f";
+    sha256 = "sha256-irMN/enoo90nYLfvSOScZoYdvhZKvqqp+grZB2BQD9o=";
+  };
+
+  nativeBuildInputs = [
+    inkscape
+    xcursorgen
+  ];
+
+  postPatch = ''
+    patchShebangs .
+    # The script tries to build in its source directory...
+    substituteInPlace build.sh --replace \
+      ': "''${BUILD_DIR:="$SCRIPT_DIR"/build}"' \
+      "BUILD_DIR=$(pwd)/build"
+    substituteInPlace build.sh --replace \
+      ': "''${OUT_DIR:="$SCRIPT_DIR"/dist}"' \
+      "OUT_DIR=$(pwd)/dist"
+  '';
+
+  buildPhase = ''
+    HOME="$NIX_BUILD_ROOT" ./build.sh
+  '';
+
+  installPhase = ''
+    make install PREFIX= DESTDIR=$out/
+  '';
+
+  meta = with lib; {
+    description = "Classic cursor with a flying style";
+    homepage = "https://github.com/varlesh/volantes-cursors";
+    license = licenses.gpl2Only;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ ambroisie ];
+  };
+}