pkgs: add bw-pass

Until `rbw` gets support for Yubikey 2FA, I still need a decent way to
query for my passwords on the command line...

This wrapper program should be good enough for basic usage with programs
that need a password command.

pkgs/bw-pass/default.nix

@@ -0,0 +1,45 @@
+{ bitwarden-cli, coreutils, jq, keyutils, lib, makeWrapper, rofi, shellcheck, stdenvNoCC }:
+stdenvNoCC.mkDerivation rec {
+  pname = "bw-pass";
+  version = "0.1.0";
+
+  src = ./bw-pass;
+
+  phases = [ "buildPhase" "installPhase" "fixupPhase" ];
+
+  buildInputs = [
+    makeWrapper
+    shellcheck
+  ];
+
+  buildPhase = ''
+    shellcheck $src
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp $src $out/bin/${pname}
+    chmod a+x $out/bin/${pname}
+  '';
+
+  wrapperPath = lib.makeBinPath [
+    bitwarden-cli
+    coreutils
+    jq
+    keyutils
+    rofi
+  ];
+
+  fixupPhase = ''
+    patchShebangs $out/bin/${pname}
+    wrapProgram $out/bin/${pname} --prefix PATH : "${wrapperPath}"
+  '';
+
+  meta = with lib; {
+    description = "A simple script to query a password from bitwarden";
+    homepage = "https://gitea.belanyi.fr/ambroisie/nix-config";
+    license = with licenses; [ mit ];
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ ambroisie ];
+  };
+}