home: create 'modules/home' folder

Consolidating all modules under the same path, to clear out the
top-level directory.

modules/home/firefox/default.nix

@@ -0,0 +1,80 @@
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.my.home.firefox;
+in
+{
+  imports = [
+    ./tridactyl
+  ];
+
+  options.my.home.firefox = with lib; {
+    enable = mkEnableOption "firefox configuration";
+
+    tridactyl = {
+      enable = mkOption {
+        type = types.bool;
+        description = "tridactyl configuration";
+        example = false;
+        default = config.my.home.firefox.enable;
+      };
+    };
+
+    ff2mpv = {
+      enable = mkOption {
+        type = types.bool;
+        description = "ff2mpv configuration";
+        example = false;
+        default = config.my.home.mpv.enable;
+      };
+    };
+  };
+
+  config.programs.firefox = lib.mkIf cfg.enable {
+    enable = true;
+
+    package = pkgs.firefox.override {
+      nativeMessagingHosts = ([ ]
+        ++ lib.optional cfg.tridactyl.enable pkgs.tridactyl-native
+        # Watch videos using mpv
+        ++ lib.optional cfg.ff2mpv.enable pkgs.ambroisie.ff2mpv-go
+      );
+    };
+
+    profiles = {
+      default = {
+        id = 0;
+
+        settings = {
+          "browser.bookmarks.showMobileBookmarks" = true; # Mobile bookmarks
+          "browser.download.useDownloadDir" = false; # Ask for download location
+          "browser.in-content.dark-mode" = true; # Dark mode
+          "browser.newtabpage.activity-stream.feeds.section.topstories" = false; # Disable top stories
+          "browser.newtabpage.activity-stream.feeds.sections" = false;
+          "browser.newtabpage.activity-stream.feeds.system.topstories" = false; # Disable top stories
+          "browser.newtabpage.activity-stream.section.highlights.includePocket" = false; # Disable pocket
+          "extensions.pocket.enabled" = false; # Disable pocket
+          "media.eme.enabled" = true; # Enable DRM
+          "media.gmp-widevinecdm.enabled" = true; # Enable DRM
+          "media.gmp-widevinecdm.visible" = true; # Enable DRM
+          "signon.autofillForms" = false; # Disable built-in form-filling
+          "signon.rememberSignons" = false; # Disable built-in password manager
+          "ui.systemUsesDarkTheme" = true; # Dark mode
+        };
+
+        extensions = with pkgs.nur.repos.rycee.firefox-addons; ([
+          bitwarden
+          consent-o-matic
+          form-history-control
+          reddit-comment-collapser
+          reddit-enhancement-suite
+          refined-github
+          sponsorblock
+          ublock-origin
+        ]
+        ++ lib.optional (cfg.tridactyl.enable) tridactyl
+        ++ lib.optional (cfg.ff2mpv.enable) ff2mpv
+        );
+      };
+    };
+  };
+}

modules/home/firefox/tridactyl/default.nix

@@ -0,0 +1,28 @@
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.my.home.firefox.tridactyl;
+
+  term = config.my.home.terminal.program;
+
+  vimCommandLine = {
+    alacritty = ''-e "vim" "%f" "+normal!%lGzv%c|"'';
+    # Termite wants the whole command in a single argument...
+    termite = ''-e "vim %f '+normal!%lGzv%c|'"'';
+  };
+in
+{
+  config = lib.mkIf cfg.enable {
+    xdg.configFile."tridactyl/tridactylrc".source = pkgs.substituteAll {
+      src = ./tridactylrc;
+
+      editorcmd = lib.concatStringsSep " " [
+        # Use my configured terminal
+        term
+        # Make it easy to pick out with a window class name
+        "--class tridactyl_editor"
+        # Open vim with the cursor in the correct position
+        vimCommandLine.${term}
+      ];
+    };
+  };
+}

modules/home/firefox/tridactyl/tridactylrc

@@ -0,0 +1,82 @@
+" Shamelessly taken from bovine3dom's example configuration file from the docs
+
+" Basics {{{
+" Use dark color scheme
+colorscheme dark
+
+" Make tridactyl open Vim in my prefered terminal
+set editorcmd @editorcmd@
+
+" Remove editor file after use
+alias editor_rm composite editor | jsb -p tri.native.run(`rm -f '${JS_ARG[0]}'`)
+bind --mode=insert <C-i> editor_rm
+bind --mode=input <C-i> editor_rm
+" }}}
+
+" Binds {{{
+" Reddit et al. {{{
+" Toggle comments on Reddit, Hacker News, Lobste.rs
+bind ;c hint -Jc [class*="expand"],[class*="togg"],[class="comment_folder"]
+
+" Make `gu` take me back to subreddit from comments
+bindurl reddit.com gu urlparent 3
+
+" Only hint search results on Google
+bindurl www.google.com f hint -Jc #search div:not(.action-menu) > a
+bindurl www.google.com F hint -Jbc #search div:not(.action-menu) > a
+
+" Only hint search results on DuckDuckGo
+bindurl ^https://duckduckgo.com f hint -Jc [data-testid="result-title-a"]
+bindurl ^https://duckduckgo.com F hint -Jbc [data-testid="result-title-a"]
+
+" Only hint item pages on Hacker News
+bindurl news.ycombinator.com ;f hint -Jc .age > a
+bindurl news.ycombinator.com ;F hint -Jtc .age > a
+" }}}
+
+" Better bindings {{{
+" Handy multiwindow binds
+bind gd tabdetach
+bind gD composite tabduplicate; tabdetach
+
+" Duplicate a tab without detaching window
+bind <Space>d tabduplicate
+
+" Make yy use canonical links on the few websites that support them
+bind yy clipboard yankcanon
+" }}}
+
+" Search {{{
+" Case insensitive only if fully lowercase
+set findcase smart
+
+" Search forward/backward
+bind / fillcmdline find
+bind ? fillcmdline find -?
+
+" Go to next/previous match
+bind n findnext 1
+bind N findnext -1
+
+" Because :nohls never works
+bind <Space><Space> nohlsearch
+
+" Use browser's native find when using Ctrl-F
+unbind <C-f>
+" }}}
+" }}}
+
+" Redirections {{{
+" Always redirect Reddit to the old site
+autocmd DocStart ^http(s?)://www.reddit.com js tri.excmds.urlmodify("-t", "www", "old")
+" Use a better Twitter front-end
+autocmd DocStart ^http(s?)://twitter.com js tri.excmds.urlmodify("-t", "twitter.com", "nitter.net")
+" }}}
+
+" Disabled websites {{{
+blacklistadd netflix.com
+blacklistadd primevideo.com
+blacklistadd jellyfin.belanyi.fr
+" }}}
+
+" vim: set filetype=vim foldmethod=marker: