nix: add flake

This also enables building the PDF files using `nix build`
2021-02-25 14:05:30 +00:00 · 2021-02-25 14:05:30 +00:00 · ea663ea04a
commit ea663ea04a
parent f663253642
2 changed files with 97 additions and 0 deletions
--- a/flake.nix
+++ b/flake.nix
@ -0,0 +1,55 @@
+{
+  description = "Ambroisie's CV";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs";
+    futils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = { self, nixpkgs, futils } @ inputs:
+    futils.lib.eachSystem futils.lib.allSystems (system:
+      let
+        inherit (nixpkgs) lib;
+        pkgs = nixpkgs.legacyPackages.${system};
+        buildInputs = with pkgs; [
+          gnumake
+          (texlive.combine {
+            inherit (texlive)
+              scheme-small
+              # Build script
+              latexmk
+              # Extra packages needed
+              clearsans
+              fontaxes
+              textpos
+              ifmtarg
+              marvosym
+              ;
+          })
+        ];
+      in
+      {
+        devShell = pkgs.mkShell {
+          name = "cv";
+          inherit buildInputs;
+        };
+
+        defaultPackage = pkgs.stdenvNoCC.mkDerivation {
+          pname = "cv";
+          version = self.rev or "dirty";
+          src = ./.;
+
+          inherit buildInputs;
+
+          buildPhase = ''
+            make
+          '';
+
+          installPhase = ''
+            install -Dm644 en.pdf $out/share/en.pdf
+            install -Dm644 fr.pdf $out/share/fr.pdf
+          '';
+        };
+      }
+    );
+}